Chapter 3 - Status Bar
[STATUS LINE]
To say the player's capitalised surroundings:
let the masthead be "[the player's surroundings]" in upper case;
say the masthead.
Table of Fancy Status
left | central | right |
"Location: [the player's capitalised surroundings] ([map region of the location])" | "" | "Score: [score]" |
"Near: [if a room is adjacent][the list of adjacent rooms][end if][if a room is adjacent and a door is visible], [end if][if a door is visible][the list of visible doors][end if]" | "" | "" |
Rule for constructing the status line:
fill status bar with Table of Fancy Status;
rule succeeds.
Rule for printing the name of an unvisited room (called the target) while constructing the status line:
let aim be the best route from the location to the target;
say "somewhere [aim]".
After printing the name of a visited room (called the target) while constructing the status line:
let aim be the best route from the location to the target;
if aim is not nothing:
say " ([aim])".
Rule for printing the name of a direction (called the aim) while constructing the status line:
choose row with a heading of the aim in the Table of Abbreviation;
say "[shortcut entry]".
Table of Abbreviation
heading | shortcut |
north | "N" |
northeast | "NE" |
northwest | "NW" |
east | "E" |
southeast | "SE" |
south | "S" |
southwest | "SW" |
west | "W" |
up | "U" |
down | "D" |
inside | "in" |
outside | "out" |
fore | "F" |
aft | "A" |
port | "P" |
starboard | "S" |