Nowheresville — 50 of 60

Section Nice House

[THE BRASS KEY]

The brass key is a thing.

The brass key is in the Nice House.

Understand "key" as the brass key.

The brass key is unpoked.

The brass key unlocks the blue door.

The description of brass key is "An ordinary key made of brass."

[BLUE DOOR]

The blue door is a locked door.

The blue door is north from First Avenue East and south from Nice House.

The description of the blue door is "The wooden door of the nice house is painted blue. It has a large keyhole and a noticeable gap at the bottom where the door doesn't seal."

The large keyhole is part of the blue door.

The large keyhole is a container.

Understand "keyhole" or "hole" or "key hole" as the large keyhole.

The description of the large keyhole is "[if the pokedness of the brass key is poked]You see light through the keyhole.[otherwise]You see no light through the keyhole, almost as if an object is blocking the hole.[end if]".

Check inserting something into the large keyhole:

if the blue door is locked:

if the noun is the straightened hanger:

say "You push the straightened hanger into the keyhole...";

continue the action;

if the noun is the coathanger:

say "The hanger in its present shape will not fit into the keyhole.";

stop the action;

if the noun is the pin:

say "You insert the tip of the pin barely into the keyhole, but nothing is accomplished.";

stop the action;

otherwise:

say "You can't quite manage to fit the [noun] into the keyhole.";

stop the action;

otherwise:

say "The blue door is already unlocked.";

stop the action.

After inserting something into the large keyhole:

if the noun is the straightened hanger:

if the brass key is unpoked:

if the paper is gapped:

say "You hear a *CLINK* sound on the other side of the door.";

now the brass key is poked;

now the paper is keyed;

otherwise:

say "You hear a *CLINK* sound on the other side of the door.";

now the brass key is poked;

otherwise:

say "You insert the straightened hanger into the keyhole, but nothing happens."

The noticeable gap is part of the blue door.

The noticeable gap is a container.

Understand "gap" or "crack" as the noticeable gap.

The description of the noticeable gap is "The blue door doesn't seal tightly. There is a noticeable gap under it, between the bottom of the door and the ground."

Check inserting something into the noticeable gap:

if the blue door is closed:

if the noun is the paper:

say "You push the sheet of paper through the noticeable gap under the door, leaving just enough of the page outside that you can easily retrieve it.";

now the paper is gapped;

now the paper is in the noticeable gap;

stop the action;

if the noun is the pin:

say "You push the pin under the door; but nothing happens, so you fish it back out again.";

stop the action;

if the noun is the coathanger:

say "The hanger in its present shape will not fit under the door.";

stop the action;

if the noun is the straightened hanger:

if the brass key is in the Nice House:

if the brass key is poked:

say "You fish around under the door with the straightened hanger until eventually you manage to retrieve the brass key.";

now the player carries the brass key;

stop the action;

otherwise:

say "You fish around under the door with the straightened hanger, but nothing is accomplished.";

stop the action;

otherwise:

say "You fish around under the door with the straightened hanger, but nothing is accomplished.";

stop the action;

otherwise:

say "The [noun] won't fit under the door.";

stop the action;

otherwise:

say "The blue door is already open.";

stop the action.

Carry out taking the paper:

if the paper is in the noticeable gap:

if brass key is in the Nice House:

if the paper is keyed:

say "You retrieve the paper and, along with it, a brass key.";

now the player carries the brass key;

now the paper is ungapped;

now the paper is unkeyed;

continue the action;

otherwise:

say "You retrieve the paper from the gap under the door.";

now the paper is ungapped;

now the player carries the paper;

stop the action;

otherwise:

say "You retrieve the paper from the gap under the door.";

now the paper is ungapped;

now the player carries the paper;

stop the action;

otherwise:

continue the action.

Instead of putting something under the blue door:

try inserting the noun into the noticeable gap.

[NICE HOUSE]

There is a room called Nice House.

The description of Nice House is "The house is the epitome of [']50s class and taste. Pale blue wallpapered walls with white stripes. End tables with brocaded tablecloths and fancy flower vases. Various wooden display cases, contain things like plates and figurines. In the center of the room is a [large sofa] with an embroidered cloth draped over it, with two [armchair]s and a [coffee table]. An [blue door] opens to the south."

The blue walls are scenery in the Nice House. Understand "wall" or "walls" or "wallpaper" or "wall paper" or "stripes" or "white stripes" as the blue walls.

The description of the blue walls is "The walls are covered in pale blue wallpaper with white stripes."

The end tables are scenery in the Nice House. Understand "table" or "tables" as the end tables.

The description of the end tables is "There are a couple of expensive-looking wooden end tables with brocaded tablecloths and fancy flower vases on them."

The brocaded tablecloths are scenery in the Nice House. Understand "tablecloth" or "tablecloths" or "gold" or "fabric" or "brocade" or "brocade tablecloth" or "table cloth" as the brocaded tablecloths.

The description of tablecloths is "Fancy white tablecloths with gold weaved into the fabric."

The fancy flower vases are scenery in the Nice House. Understand "flower vases" or "flower vase" or "vases" or "vase" as the fancy flower vases.

The description of the fancy flower vases is "The vases here are such works of art it seems like a shame to put flowers in them."

The white lillies are scenery in the Nice House. Understand "flower" or "flowers" or "lily" or "lilies" as the white lillies.

The description of the white lillies is "The white lilies are pretty, if a bit funereal."

The large sofa is a supporter in the Nice House. Understand "sofa" or "cushion" or "cushions" or "couch" as the large sofa.

The large sofa is enterable.

The description of the large sofa is "A navy blue sofa with oversized cushions. It looks quite comfortable."

The embroidered cloth is scenery in the Nice House. Understand "cloth" as the embroidered cloth.

The description of the embroidered cloth is "Draped over the sofa is a tasefully embroidered cloth that couldn't quite pass as a blanket."

The armchair is a supporter in Nice House. Understand "chair" or "chairs" or "armchairs" as the armchair.

The armchair is enterable.

The description of the armchair is "In the center of the room, near the sofa and coffee table, are a pair of matching blue armchairs."

The coffee table is scenery in Nice House. Understand "table" as the coffee table.

The description of the coffee table is "An oval-shaped cherry coffee table."

The display cases are scenery in the Nice House. Understand "case" or "plate" or "plates" as the display cases.

The description of the display cases is "There are various wooden display cases around the walls, containing things like plates and figurines. One particular [figurine cabinet] catches your eye."

The figurines are scenery in the Nice House.

The description of the figurines is "All of the figurines resemble someone from this town. [if figurine of yourself is in the figurine cabinet] One of them looks like you.[end if]"

[Figurine Cabinet]

The figurine cabinet is a fixed in place container in Nice House.

Figurine Cabinet is openable and closed.

Figurine Cabinet is transparent.

Figurine Cabinet is scenery.

The description of Figurine cabinet is "A fine-grain wooden cabinet with glass doors. Many well-made figurines are contained within. Oddly, a few are decked out in military equipment. All resemble someone from the town."

Before opening Figurine Cabinet:

say "It's locked.";

stop the action.

The block attacking rule does nothing when attacking the figurine cabinet.

Carry out attacking the closed Figurine cabinet:

increase the score by 1;

now Figurine cabinet is open;

say "KRUNCH! The glass doors shatter into a thousand shards of glass. Now you can take anything inside. The cabinet contains [a list of things in Figurine cabinet]."

[In case I forgot to mention this, we should consider maybe adding another item to this particular chain.]

Check attacking the open figurine cabinet:

say "There's no more point in that.";

stop the action.

Instead of closing the open Figurine Cabinet:

say "You can't close it, its door is smashed open."

Instead of hitting the figurine cabinet with the clawhammer:

try attacking the figurine cabinet.

Instead of hitting the glass doors with the clawhammer:

try attacking the figurine cabinet.

The glass doors are part of the Figurine Cabinet. Understand "doors" or "door" or "glass" as the glass doors.

The description of the glass doors is "The figurine cabinet has doors made of glass."

Instead of attacking the glass doors:

try attacking the figurine cabinet.

[Figurine of Yourself]

The figurine of yourself is a thing in Figurine Cabinet.

Understand "figurine of me" or "figurine of myself" or "figurine of max" as the figurine of yourself.

The description of the Figurine of Yourself is "A painted figurine made of porcelain, wearing shabby clothes.[if the player carries the figurine of yourself] It feels heavier than it should.[end if]"

[Do we want this to contain a key or not?]

The block attacking rule does nothing when attacking the figurine of yourself.

Carry out attacking the Figurine of yourself:

increase the score by 1;

say "You smash the figurine to pieces, revealing an ornate key.";

now the figurine of yourself is nowhere;

now the player carries the ornate key.

Instead of hitting the figurine of yourself with the clawhammer:

try attacking the figurine of yourself.

[THE ORNATE KEY]

The ornate key is a thing.

The ornate key is nowhere.

Understand "key" as the ornate key.

The ornate key unlocks the weathered door.

The description of ornate key is "A key covered in golden filigree."