Nowheresville — 30 of 60

Section Junkyard

There is a room called Junkyard. Junkyard is west from Union Street South.

The description of Junkyard is "What a load of junk! Between the bits of assorted junk, you can see a discarded boiler and an old fridge. Is that an toilet? Wow.[paragraph break]You can see the path back to the street in the east."

The junk is scenery in the junkyard. Understand "garbage" as the junk.

The description of the junk is "You can see all manner of assorted garbage here. Among it are a discarded boiler, an old fridge, and a toilet."

The dusty path is scenery in Junkyard.

The printed name of the dusty path is "path".

Understand "path" or "road" or "street" or "dirt road" as the dusty path.

The description of the dusty path is "A tidy dirt path leads east to the main road."

The boiler is scenery in Junkyard. Understand "discarded boiler" as the boiler.

The description of the boiler is "You've never understood what a boiler is, but you think this round large metal thing is one."

The toilet is scenery in Junkyard.

The description of the toilet is "It looks like it came straight off a factory assembly line. Why someone threw it out is anyone's guess."

[OLD FRIDGE]

The old fridge is a fixed in place container in Junkyard. Understand "fridge" or "refrigerator" or "latch" or "rusty latch" as the old fridge.

The old fridge is scenery.

The old fridge is locked, openable and closed.

The description of the old fridge is "It's weird, apparently the old refrigerator has a latch to keep it closed. That sounds like a safety hazard. It seems to be rusted shut, you'll have to find some other way to get it open."

Instead of doing something with the old fridge:

if the guard dog is in the Junkyard:

if the guard dog is undrugged:

say "The guard dog growls menacingly. You back away from the old fridge.";

stop the action;

otherwise:

continue the action;

otherwise:

continue the action.

Check opening the locked fridge:

say "It appears the latch is rusted shut, you'll have to find some other way to get it open.";

stop the action.

Carry out wiping the old fridge with the oily rag:

say "You rub the rusty latch with the oily rag. After a while, you get enough of the rust off that you can open it. Satisfied, you throw the oily rag away.";

now the old fridge is unlocked;

increase the score by 1;

rule succeeds.

After wiping the old fridge with the oily rag:

now the oily rag is nowhere.

Before cleaning the old fridge with the oily rag:

try wiping the old fridge with the oily rag.

Before rubbing the oily rag on the old fridge:

try wiping the old fridge with the oily rag.

Before lubricating the old fridge with the oily rag:

try wiping the old fridge with the oily rag.

[GUARD DOG]

The guard dog is an animal in the Junkyard. Understand "dog" or "bulldog" as the guard dog.

The guard dog is undrugged.

The guard dog is hittable.

The feedability of the guard dog is feedable.

The description of the guard dog is "A very muscular bulldog is chained up here.[if the druggedness of the guard dog is undrugged] It looks angry or hungry or both.[otherwise] It is curled up, fast asleep.[end if]"

After giving the raw beef to the guard dog:

say "The guard dog looks happy for the moment it takes to gobble down the raw beef, then it goes back to looking surly again.";

now the raw beef is in Butcher.

Instead of feeding the raw beef to the guard dog:

try giving the raw beef to the guard dog.

After giving the drugged beef to the guard dog:

say "The guard dog gobbles down the drugged beef, then curls up for a nap.";

increase the score by 1;

now the druggedness of the guard dog is drugged;

now the drugged beef is nowhere.

Instead of feeding the drugged beef to the guard dog:

try giving the drugged beef to the guard dog.

The block giving rule does nothing when giving the raw beef to the guard dog.

The block giving rule does nothing when giving the drugged beef to the guard dog.

Instead of shooting the guard dog with the toy gun:

say "BANG![paragraph break]The guard dog dissolves into a cloud of crackling blue light and then is gone.";

now the guard dog is nowhere.

Instead of hitting the guard dog with the clawhammer:

say "Let sleeping dogs lie."

Instead of attacking the undrugged guard dog:

say "There's no way you're winning this fight."

Instead of attacking the drugged guard dog:

say "Let sleeping dogs lie."

[TALKING TO GUARD DOG]

Instead of talking to the undrugged guard dog:

say "'RUFF!'"

Report telling undrugged guard dog about something:

say "[one of]'BARK!'[or]'AWOO!'[cycling]".

Report asking undrugged guard dog about something:

say "[one of]'ARF?'[or]'*whine*'[cycling]".

Instead of talking to the drugged guard dog:

say "'ZZZ...'"

Report telling drugged guard dog about something:

say "'ZZZ...'"

Report asking drugged guard dog about something:

say "'ZZZ...'"

The block asking rule does nothing when asking the guard dog about something.

The block telling rule does nothing when telling the guard dog about something.

[CLAWHAMMER]

The clawhammer is a thing in the old fridge.

Understand "hammer" or "claw" as the clawhammer.

The description of the clawhammer is "The hammer has a blunt end for striking and a claw end for prying."

[STEP LADDER]

The step ladder is an enterable supporter in Junkyard. The ladder is not fixed in place. "A 2-foot aluminum step ladder leans against the wall here."

Description of the step ladder is "A 2-foot aluminum step ladder." Understand "ladder" or "step" or "stepladder" as the step ladder.

Instead of climbing the ladder, try entering the noun.

Instead of doing something with the step ladder:

if the guard dog is in the Junkyard:

if the guard dog is undrugged:

say "The guard dog growls menacingly. You back away from the step ladder.";

stop the action;

otherwise:

continue the action;

otherwise:

continue the action.